Penggunaan Prosedur Function Pada VB.Net

Prosedur adalah sebuah kelompok pernyataan yang bersama-sama melakukan tugas ketika dipanggil. Setelah prosedur dijalankan, kontrol kembali ke pernyataan memanggil prosedur. VB.Net memiliki dua jenis prosedur:

• Functions
• Sub procedures Atau Subs

Function sendiri ketika dieksekusi mengembalikan nilai, sedangkan Sub tidak meminta mengembalikan nilai ketika dieksekusi. Pernyataan function digunakan untuk menyatakan nama, parameter dan bagian function .Sintaks untuk pernyataan funtion bisa anda lihat berikut ini:

[Modifiers] Function FunctionName [(ParameterList)] As ReturnType
    [Statements]
End Function

Penejelasan:

• Pengubah: menetapkan tingkat akses fungsi; nilai-nilai yang tersedia: Public, Private, Protected, Friend, Protected Friend and information regarding overloading, overriding, sharing, and shadowin
• FunctionName: menunjukkan nama fungsi
• ParameterList: menentukan daftar parameter
• ReturnType: menentukan tipe data dari variabel fungsi kembali

Contoh

Kode berikut menunjukkan fungsi FindMax yang mengambil dua nilai integerdan kembali lebih besar dari dua.

Function FindMax(ByVal num1 As Integer, ByVal num2 As Integer) As Integer
   ' local variable declaration */
   Dim result As Integer
   If (num1 > num2) Then
       result = num1
   Else
       result = num2
   End If
   FindMax = result
End Function

Function Returning a Value

• Dalam VB.Net, fungsi dapat mengembalikan nilai untuk kode panggilan dalam duacara:
• Dengan menggunakan pernyataan kembali
• Dengan menetapkan nilai ke nama fungsi
• Contoh berikut menunjukkan menggunakan FindMax fungsi:

Module myfunctions
   Function FindMax(ByVal num1 As Integer, ByVal num2 As Integer) As Integer
      ' local variable declaration */
      Dim result As Integer
      If (num1 > num2) Then
          result = num1
      Else
          result = num2
      End If
      FindMax = result
   End Function
   Sub Main()
      Dim a As Integer = 100
      Dim b As Integer = 200
      Dim res As Integer
      res = FindMax(a, b)
      Console.WriteLine("Max value is : {0}", res)
      Console.ReadLine()
   End Sub
End Module

Dan bila dijalankan maka hasil dari kode tersebut adalah sebagai berikut:

Max value is : 200

Recursive Function

Fungsi dapat memanggil dirinya. Hal ini dikenal sebagai rekursi. Berikut adalah contohyang menghitung faktorial untuk nomor tertentu menggunakan fungsi rekursif:

Module myfunctions
   Function factorial(ByVal num As Integer) As Integer
      ' local variable declaration */
      Dim result As Integer
      If (num = 1) Then
          Return 1
      Else
          result = factorial(num - 1) * num
          Return result
      End If
   End Function
   Sub Main()
      'calling the factorial method
      Console.WriteLine("Factorial of 6 is : {0}", factorial(6))
      Console.WriteLine("Factorial of 7 is : {0}", factorial(7))
      Console.WriteLine("Factorial of 8 is : {0}", factorial(8))
      Console.ReadLine()
   End Sub
End Module

Dan bila dijalankan maka hasil dari kode tersebut adalah sebagai berikut:

Factorial of 6 is: 720
Factorial of 7 is: 5040
Factorial of 8 is: 40320

Param Arrays

Contoh penggunaan parameter yang bertipe data array:

Module myparamfunc
   Function AddElements(ParamArray arr As Integer()) As Integer
      Dim sum As Integer = 0
      Dim i As Integer = 0
      For Each i In arr
          sum += i
      Next i
      Return sum
   End Function
   Sub Main()
      Dim sum As Integer
      sum = AddElements(512, 720, 250, 567, 889)
      Console.WriteLine("The sum is: {0}", sum)
      Console.ReadLine()
   End Sub
End Module

Dan bila dijalankan maka hasil dari kode tersebut adalah sebagai berikut:

The sum is: 2938

Passing Arrays as Function Arguments

Anda dapat melewati array sebagai argumen fungsi dalam VB.Net. Contoh berikutmenunjukkan ini:

Module arrayParameter
   Function getAverage(ByVal arr As Integer(), ByVal size As Integer) As Double
      'local variables
       Dim i As Integer
       Dim avg As Double
       Dim sum As Integer = 0
       For i = 0 To size - 1
           sum += arr(i)
       Next i
       avg = sum / size
       Return avg
    End Function
    Sub Main()
        ' an int array with 5 elements '
        Dim balance As Integer() = {1000, 2, 3, 17, 50}
        Dim avg As Double
        'pass pointer to the array as an argument 
        avg = getAverage(balance, 5)
        ' output the returned value '
        Console.WriteLine("Average value is: {0} ", avg)
        Console.ReadLine()
    End Sub
End Module

Dan bila dijalankan maka hasil dari kode tersebut adalah sebagai berikut:

Average value is: 214.4

Demikianlah tutorial tentang penggunaan prosedur pada vb.net, semoga bermanfaat untuk anda.

sumber:http://www.tutorialspoint.com/